[DofusLog] Simplifiez vous la vie...

Voilà , ça fait quelques mois que j'suis sur un petit soft rigolo et quelques semaines que j'ai terminé une version qui marche à 99%.

Code:

#include <GUIConstants.au3>
Dim $aLog[4]
$fichier = FileOpenDialog(@ScriptName & " - Sélectionnez ou créez un fichier contenant vos logs", @ScriptDir, "Text files (*.txt)|All files (*.*)", 8, "Log.txt") ;Spécial pour JoL ^^
;$fichier = @ScriptDir & "\Log.txt" ;Spécial pour moi. ^^
$existe = _FileReadToArray2($fichier, $aLog)
$prgChemin = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Ankama\Dofus", "Path")
Global $compte = 1
Global $FenBase
Global $Label
Global $Lancer
Global $Modifier
Global $Nouveau
$Padpass = ""

If Not $existe Then
   Modifier($compte, $fichier)
   $compte = 3 * ($compte - 1) + 1
EndIf
_FileReadToArray2($fichier, $aLog)
$aLog[0] = (UBound($aLog) - 1) / 3 ;temporaire ! -Mais bien utile, en fait.. Je garde. ^^
Dim $Radio[$aLog[0] + 1]
Fenetre()

While 1
   $msg = GUIGetMsg()
   Switch $msg
      Case 0         
         ContinueLoop

      Case $GUI_EVENT_CLOSE
         GUIDelete($FenBase)
         Exit

      Case $Radio[1] To $Radio[$aLog[0]]
         If $msg <> $Radio[$compte] Then
            GUICtrlSetPos($Radio[$compte], 5, 27 + (($compte - 1) * 7 * 3))
            While $msg <> $Radio[$compte]
               $compte += 1
               If $compte > $aLog[0] Then
                  $compte = 1
               EndIf
            WEnd
            GUICtrlSetPos($Radio[$compte], 15, 30 + (($compte - 1) * 7 * 3))
         EndIf

      Case $Modifier
         Modifier($compte, $fichier)
         GUICtrlSetData($Radio[$compte], $aLog[($compte - 1) * 3 + 1])

      Case $Nouveau
         ReDim $aLog[UBound($aLog) + 3]
         $aLog[0] = (UBound($aLog) - 1) / 3 ;temporaire !
         Modifier($aLog[0], $fichier)
         ReDim $Radio[UBound($Radio) + 1]
         GUIDelete($FenBase)
         Fenetre()

      Case $Lancer
         $compte = ($compte - 1) * 3 + 1
         If $aLog[$compte + 2] <> $Padpass Then
            If InputBox( @ScriptName & " - Code du compte " & $aLog[$compte], "Veuillez entrer le mot de passe pour accéder au compte de " & $aLog[$compte] & " :", "", "°M") <> $aLog[$compte + 2] Then
               MsgBox( 0x232, @ScriptName & " - Se Logguer", "Identification ratée.")
               Exit
            EndIf
         EndIf
         ExitLoop
   EndSwitch
WEnd
GUIDelete($FenBase)

If MsgBox(0x51, @Scriptname, "Lancement de la fenêtre Dofus !" & @CRLF & "Annuler pour fermer le script.", 2) = 2 Then
   Exit ;Juste pour test au-dessus, sans démarrage du client
EndIf

ShellExecute("Dofus.exe","", $prgChemin)
Do
   Do
      sleep(20)
   Until MouseGetCursor( ) = 5 ;Curseur 5 = Curseur d'édition de texte
   If WinActive("Dofus") Then
      MouseClick("left")
   EndIf
   Sleep(20)
Until WinActive("Dofus")
WinSetTitle("Dofus", "", "Dofus - " & $aLog[$compte])
;~ Send("^f") ;Mode "plein écran"
Send($aLog[$compte + 1]) ;"login{tab}mdp"

Do
   sleep(20)
   $cur = MouseGetPos()
Until ( (MouseGetCursor() = 0) And (PixelGetColor($cur[0], $cur[1]) = 16750848) ) ;Curseur 0 = Curseur Web/Couleur 16750848 = #FF9900 = orange. Donc : que le pointeur soit sur du orange + en mode "web" (sur le bouton "ok", quoi)
MouseClick("left")

;============================================================
Func Fenetre()
   $FenBase = GUICreate(@ScriptName, 200, 30 + $aLog[0] * 7 * 3 + 30)
   $Label = GUICtrlCreateLabel("Choisissez un compte à Logger :", 5, 5)
   
   GUIStartGroup()
   $Lancer = GUICtrlCreateButton("Lancer !", 150, 18 + 7 * $aLog[0], 48)
   $Modifier = GUICtrlCreateButton("Modifier", 150, 33 + $aLog[0] * 7 * 3, 48)
   $Nouveau = GUICtrlCreateButton("Nouveau", 1, 33 + $aLog[0] * 7 * 3)
   
   $compteCourant = 1
   While $compteCourant <= $aLog[0]
      $Radio[$compteCourant] = GUICtrlCreateRadio($aLog[($compteCourant - 1) * 3 + 1], 5, 27 + (($compteCourant - 1) * 7 * 3), 130)
      $compteCourant += 1
   WEnd
   GUICtrlSetState ($Radio[$compte], $GUI_CHECKED)
   GUICtrlSetPos($Radio[$compte], 15, 30 + ($compte - 1) * 3 * 7)
   
   GUISetState()
EndFunc

Func Modifier($compteCourant, $fich)
   $compteCourant = 3 * ($compteCourant - 1) + 1
   Do
      $aLog[$compteCourant] = InputBox( @ScriptName & " - Nouveau log", "Veuillez entrer un pseudonyme au compte :", $aLog[$compteCourant], " M") ;Pratique pour le débug, l'affichage par défaut de l'élément choisit
      If @Error = 1 Then
         Return
      EndIf
   Until $aLog[$compteCourant] <> ""
   _FileWriteToLine2($fichier, $compteCourant, $aLog[$compteCourant], 1)

   Do   
      $aLog[$compteCourant + 1] = InputBox( @ScriptName & " - Nom de compte de " & $aLog[$compteCourant], "Entrez le nom de compte associé au pseudonyme " & $aLog[$compteCourant] & " :", "", " M")
      If @Error = 1 Then
         Return
      EndIf
   Until  $aLog[$compteCourant + 1] <> ""
   $aLog[$compteCourant + 1] &= "{TAB}"
   Do
      $aLog[$compteCourant + 2] = InputBox( @ScriptName & " - Mot de passe du compte de " & $aLog[$compteCourant], "Entrez le mot de passe du compte associé au pseudonyme " & $aLog[$compteCourant] & " :", "", "°M")
      If @Error = 1 Then
         Return
      EndIf
   Until $aLog[$compteCourant + 2] <> ""
   $aLog[$compteCourant + 1] &= $aLog[$compteCourant + 2]
   _FileWriteToLine2($fichier, $compteCourant + 1, $aLog[$compteCourant + 1], 1)
   
   $aLog[$compteCourant + 2] = InputBox( @ScriptName & " - Mot de passe du pseudonyme " & $aLog[$compteCourant], "Entrez un mot de passe pour utiliser le pseudonyme " & $aLog[$compteCourant] & "," & @CRLF & "Ou laissez tel-quel pour utilisation libre.", $Padpass,"°")
   _FileWriteToLine2($fichier, $compteCourant + 2, $aLog[$compteCourant + 2], 1)
EndFunc

Func _FileWriteToLine2($sFile, $iLine, $sText, $fOverWrite = 0)
   If $iLine <= 0 Then
      SetError(4)
      Return 0
   EndIf
   If Not IsString($sText) Then
      SetError(6)
      Return 0
   EndIf
   If $fOverWrite <> 0 And $fOverWrite <> 1 Then
      SetError(5)
      Return 0
   EndIf
   If Not FileExists($sFile) Then
      FileWrite($sFile, @CRLF)
   EndIf
   Local $filtxt = FileRead($sFile, FileGetSize($sFile))
   $filtxt = StringSplit($filtxt, @CRLF, 1)
   If $filtxt[0] < $iLine Then
      ReDim $filtxt[$iLine + 1]
   EndIf
   Local $fil = FileOpen($sFile, 2)
   If $fil = -1 Then
      SetError(3)
      Return 0
   EndIf
   For $i = 1 To UBound($filtxt) - 1
      If $i = $iLine Then
         If $fOverWrite = 1 Then
            If $sText <> '' Then
               If $i < UBound($filtxt, 1) - 1 Then
                  FileWrite($fil, $sText & @CRLF)
               ElseIf $i = UBound($filtxt, 1) - 1 Then
                  FileWrite($fil, $sText)
               EndIf
            Else
               If $i < UBound($filtxt, 1) - 1 Then
                  FileWrite($fil, $sText)
               EndIf
            EndIf
         EndIf
         If $fOverWrite = 0 Then
            If $i < UBound($filtxt, 1) - 1 Then
               FileWrite($fil, $sText & @CRLF)
               FileWrite($fil, $filtxt[$i] & @CRLF)
            ElseIf $i = UBound($filtxt, 1) - 1 Then
               FileWrite($fil, $sText & @CRLF)
               FileWrite($fil, $filtxt[$i])
            EndIf
         EndIf
      ElseIf $i < UBound($filtxt, 1) - 1 Then
         FileWrite($fil, $filtxt[$i] & @CRLF)
      ElseIf $i = UBound($filtxt, 1) - 1 Then
         FileWrite($fil, $filtxt[$i])
      EndIf
   Next
   FileClose($fil)
   Return 1
EndFunc  ;==>_FileWriteToLine2

Func _FileReadToArray2($sFilePath, ByRef $aArray)
   Local $hFile
   $hFile = FileOpen($sFilePath, 0)
   If $hFile = -1 Then
      SetError(1)
      Return 0
   EndIf
   $aArray = StringSplit(StringStripCR(FileRead($hFile, FileGetSize($sFilePath))), @LF)
   FileClose($hFile)
   Return 1
EndFunc  ;==>_FileReadToArray

Spoiler:

Spoiler:

Line -1:
Error: Array variable has incorrect number of subscripts or subscript dimension range exeeded

Spoiler: